nlbegin

概要

XYデータの非線形曲線フィッティングセッションを開始します

追加の情報

Xファンクションは Auto GetNダイアログ用にデザインされていません。

この機能はOrigin8.0 SR5で更新されています。詳細は、リリースノート のセクションをご覧下さい。

コマンドラインでの使用法

nlbegin iy:=1 func:=gauss nltree:=tt; // gaussモデルを使用して、アクティブプロットのフィットを実行

nlbegin iy:=(1,2) func:=expgrow1 nltree:=tt;// expgrow1モデルを実行して、列1 を X とし、列2 を Y として実行

変数

説明

非線形曲線フィットのセッションを開始します。この時、オプション設定とパラメータの初期化も行います。

nltreeはツリーノードの変数で、数多くのフィット設定やフィット結果例えば、パラメータ値や標準誤差などを読み解く際、に使用できます。以下の表はnltreeの中で最も一般的なオブジェクトです。

nltreeツリーノードの詳細について

この表はパラメータから独立したプロパティをリストします。多くのプロパティは最低1回でもフィットを反復しないとツリーに表示されません。

なお、*.pn, *.lbnのようなオブジェクトを使用する場合、フィットパラメータにアクセスする方法は2通りあります。1つ目の方法はパラメータの順番を利用してアクセスする方法です。もう1つの方法はパラメータ名を使用する事です。例えば、2つのデータセットがGauss関数でフィットされた場合、8つのフィット関数、y0, xc, w, A (1番目のデータセットのパラメータ名)とy0_2, xc_2, w_2, A_2 (2番目のデータセットのパラメータ名)があります。nltree 内にttという変数がある場合、tt.p5 と tt.y0_2 はどちらも2番目のデータセット内にあるパラメータy0_2を示します。

*.covarn と *.corrn は共分散行列とフィット結果からレポートに作成する相関行列にアクセスするのに使用します。この両方のパラメータを nltree で使用出来るようになるのはフィット結果が共分散行列と相関行列を有する時のみです。よって、スクリプトを使う必要があります。

nlend 1;

これでレポートを出力します。次のスクリプトは共分散行列のセルにアクセスする方法です。

tt.covar1[1,2]=;  //共分散行列の1行2列目のセルにアクセスする

サンプル

1.それでは、ExpGrow1 関数を使用してアクティブレイヤの最初のプロットをフィットしましょう。

パラメータ x0 と y0 の値は固定し、反復は3回とします。フィットしたデータは3列目に出力します。

fname$=system.path.program$ + "Samples\Curve Fitting\Exponential Growth.dat"; // データを準備
newbook;
impasc;
wks.addcol();
string strData$ = %(%H,$(wks.ncols)); // 追加した列の名前を確認
range fitx=1, fity=3;
plotxy (1,2);
nlbegin 1 ExpGrow1 tt;      //最初のプロットにフィット関数ExpGrow1 を使用してフィット実行
tt.x0=0;tt.f_x0=1;          // まず、x0 の値を最初の日付に固定
tt.y0=0;tt.f_y0=1;          // 同じくfix y0 を固定
tt.A1=1;
nlfit 3;                    // 反復は3 回だけ
tt.f_x0=0;tt.f_y0=0;        // x0 と y0 元に戻し、デフォルトの設定で収束するまで反復
nlfit;
fity=fit(fitx);             // フィット曲線を生成
nlend;                      // フィット過程終了
layer -i %(strData$);       // プロット内にフィット結果を含む
set %(strData$) -c 2;       // 色を赤にセット

2.これは、nlbegin を使用してフィットセッションを開始する例です。その後、nlparaを使用してパラメータダイアログを開き、初期値と境界設定を編集します。

最後に、nlfitを使用して、フィットの続きを行います。

nlbegin iy:=2 func:=Gauss;	// make sure col(1)とcol(2)にデータがあることを確認
nlpara;		                //ダイアログを開いてパラメータ値を確認

// フィット完了のために次のコマンドを実行
nlfit;
nlend 1;

3.このサンプルは使用するつもりだった関数がデータにとって適切ではないと判断した時に、nlfn を使用してフィット関数をリセットします。

nlbegin iy:=2 func:=Gauss;	// col(1)&col(2) がデータを含むことを確認
nlfn Lorentz;
nlfit;
nlend 1 1;			// 自動更新でフィット結果を出力

4.複製を設定する事で、複数のピークのデータをフィットするサンプルです。

fname$=system.path.program$ + "Samples\Curve Fitting\Multiple Peaks.dat"; // データ準備
newbook;
impasc;
nlbegin (1,2) Gauss tt replica:=2;
nlfit;
nlend 1;

5.これは重み付けフィットを行う例題です

fname$=system.path.program$ + "Samples\Curve Fitting\gaussian.dat"; // データ準備
newbook;
impasc;
nlbegin (1,2,3) Gauss tt weight:=ins;	//col(3) を重みデータ列としてセットし、重み付け方法は機械的を選択
nlfit;
nlend 1;

6.共分散行列とフィット結果からレポートに作成する相関行列にアクセスするサンプルです。

fname$=system.path.program$ + "Samples\Curve Fitting\Gaussian.dat";
newbook;
impasc;
nlbegin iy:=(1,2) func:=Gauss nltree:=tt;
// 相関行列と共分散行列を出力
nlgui gg 1;
gg.Quantities.mCov = 1;
gg.Quantities.mCor = 1;
nlgui gg 0;
nlfit;
nlend 1;
tt.covar1[1,2]=;
tt.corr1[1,2]=;

7.この例題の場合、スクリプトは全体として実行してください。実行中、NLFit パラメータダイアログが開くので、設定を編集できます。OKをクリックしてダイアログを閉じるとき、次のスクリプト行(nlend 1 1;)が自動的に実行されます。

fname$=system.path.program$ + "Samples\Curve Fitting\Exponential Growth.dat"; // データ準備
newbook;
impasc;
wks.addcol();
string strData$ = %(%H,$(wks.ncols)); // 追加した列の名前を確認
range fitx=1, fity=3;
plotxy (1,2);
nlbegin 1 ExpGrow1 tt;      //最初のプロットにExpGrow1 関数を使用したフィットセッションを実行
tt.x0=0;tt.f_x0=1;          // パラメータx0 値を最初の日付で固定
tt.y0=0;tt.f_y0=1;          // 同じくパラメータ y0 を固定
tt.A1=1;
nlpara 1;         //ダイアログが開き、必要に応じて設定を変更
//OKをクリックしてダイアログを閉じると、自動的に次の行を実行
nlend 1 1;

関連 X ファンクション

nlfit, nlend, nlgui, nlpara, nlfn, nlbeginr, nlbeginz, nlbeginm, nlbegino

キーワード:回帰, NLFit