行列オブジェクトの基本操作

行列シートは複数の行列オブジェクトを持つことができ、それらは共通の次数を持ちます。行列オブジェクトはワークシートと同じように認識することができ、追加や削除ができます。以下のセクションは行列オブジェクトの基本的な操作について、実践的なサンプルを通して紹介します。

行列オブジェクトの追加または挿入

wks.nmatsを使用すると行列シート内に複数の行列オブジェクトをセットして行列オブジェクトを追加する事ができます。また、wks.addcol()の方法は行列オブジェクトを追加する際にも使用できます。

// 行列シート内に5つの行列オブジェクトをセット
wks.nmats = 5;
// 行列シートに新しい行列オブジェクトを追加
wks.addCol();
// 名前のついた行列オブジェクトを行列シートに追加
wks.addCol(Channel2);

デフォルトでは、行列シート内にある最初の行列オブジェクトが現在の行列オブジェクトとなり、wks.colを使用します。また、 wks.insert()方法は現在の行列オブジェクトの前に行列オブジェクトを挿入します。

// 新しい行列ブックを作成し、イメージサムネールを表示
newbook mat:=1;
matrix -it 1;
 
// アクティブな行列シートの中の1番目の行列オブジェクトの前に行列オブジェクトを挿入
wks.insert();
 
// 2番目の行列オブジェクトを現在のオブジェクトにする
wks.col = 2;
 
// 2番目の行列オブジェクトの前に行列オブジェクトを挿入
wks.insert();

行列オブジェクトをアクティブ化する

アクティブな行列シートの中にある行列オブジェクトをアクティブ化するにはwks.activeを使用します。

// 新しい行列ブックを作成
newbook mat:=1;
 
// アクティブな行列シートにさらに2つの行列オブジェクトを追加
wks.addCol();
wks.addCol();
 
// イメージサムネールを表示
matrix -it 1;
 
// 2番目の行列オブジェクトをアクティブにする
wks.active = 2;

イメージモードとデータモードを切り替える

matrix コマンドは行列オブジェクトのイメージモードとデータモードを切り替えるオプションを提供しています。アクティブな行列オブジェクトのみが行列シートに現れます。

matrix -ii 1;  // イメージモードで表示
matrix -ii 0;  // データモードで表示

ラベルのセット

各行列オブジェクトについてのロングネーム、コメント、単位は範囲表記を使用してセットします。

// 新しい行列ブックを作成
newbook mat:=1;
 
// 1番目の行列シートに含む行列オブジェクトの数を3つにする
wks.nMats = 3;
 
// イメージサムネールを表示
matrix -it 1;
 
// 最初の行列オブジェクトをアクティブにする
wks.active = 1;
 
// ロングネーム、単位、コメントをセット
range rx = 1;  // アクティブな行列シートの最初の行列オブジェクト
rx.lname$ = X;  // ロングネーム = X
rx.unit$ = cm;  // 単位= cm
rx.comment$ = "X Direction";  // コメント = "X Direction"
 
// 同じことを行列オブジェクト2と3にも行う
wks.active = 2;
range ry = 2;
ry.label$ = Y;  // ロングネームはこの方法でもセット可能
ry.unit$ = cm;
ry.comment$ = "Y Direction";
wks.active = 3;
range rz = 3;
rz.label$ = Z;
rz.unit$ = Pa;
rz.comment$ = Pressure;

行列オブジェクト削除する

行列オブジェクトを削除するには、deleteコマンドを使用します。

// 行列オブジェクトを範囲で削除
range rs=[mbook1]msheet1!1;  // 最初の行列オブジェクト
del rs;
// または、行列オブジェクトの名前で削除
range rs=[mbook1]msheet1!Channel2;  // オブジェクト名はChannel2
del rs;