列ラベル行データへのアクセス

はじめに

ワークシートの列ラベルの行は通常、1つもしくはそれ以上のデータ（データセット）列と関係したメタデータを含んでいます。このメタデータはLabTalkスクリプトやユーザインタフェースのさまざまな場所を通じて利用することができます。注意：


要素 使用場所 サンプル
軸タイトル

%(1,@LL)

凡例

\l(1) %(1,@LL)

テキストラベル

%(1,@LL)

プロットラベル

%(wcol(n)[L]$)
%(1,@LL)

アノテーション

%(1,@LL) = $(x), $(y,y)

列の計算式とセルの計算式

value(A[D2]$)*B (列式) =value(A[D2]$)*B1 (セル式)

スクリプト
  • 一般的なスクリプトの使用法

下のサンプルをご覧ください。

上記の要素はセルデータやプロジェクト、インポートファイルのメタデータ、プロジェクト変数などを含んだ他のタイプのプロジェクトデータの置換をサポートしています。要素による置換の使い方についての議論は要素列のリンクを参照してください。

ノートは、ワークシートの列ラベル行セルに挿入できます。また、"@@@NotesN" 構文を使用して、グラフページまたはレイアウトページに内容を追加できます。

列ラベル行のプロパティ

LabTalkスクリプトを記述する場合、 ワークシートラベル行は、次の文字を行インデックスとして使用してアクセスされます。

列のラベル行 文字 アクセス 説明
ショートネーム G 読み取り/書き込み ショートネーム (8.6 SR0).
ロングネーム L 読み取り/書き込み ロングネーム
単位 U 読み取り/書き込み 単位
コメント C 読み取り/書き込み コメント
サンプリング間隔 E 読み取り専用 サンプリング間隔（8.0 SR3より前ではRで表されます）。wks.labels(E)を使用してこの列ラベル行を表示し、wks.colを使用して間隔を設定します --以下の例を参照してください。
スパークライン S n/a スパークライン。wks.labels(S)を使用してこのラベル行を表示できます。この場合、sparklinesXファンクションを使用してプロットを表示できます。ただし、sparklinesのXファンクションを使用して、スパークラインの列ラベル行とプロットの両方を表示できます。
フィルタ F 読み取り専用 フィルタ条件 (90 SR0).
F(x)= O 読み取り/書き込み F(x)=または列値の設定式 (91 SR0).
カテゴリ O1 読み取り専用 カテゴリデータ列のカテゴリ (2015 SR2).
パラメータ Pn 読み取り/書き込み 組み込みの列パラメータ。nはパラメータインデックスです。
ユーザ-定義パラメータ Dn / <実パラメータ名> 読み取り/書き込み ユーザ定義パラメータ。nはパラメータインデックスです。 例えば、平均として1つ目のユーザパラメータの名前を変更する場合には、col(B)[D1]$ や col(B)[Mean]$　が使用できます。

サンプル

//列ラベル行の表示、非表示、または移動
wks.labels(0); //すべての列ラベル行を非表示
wks.labels(@); // インポートで単位が追加されると、単位はロングネームとコメントの間に移動し、F(x)=は一番下に
wks.labels(LUCO); //ロングネーム、単位、コメント、およびF(x)行
wks.labels(+EF);  //サンプリング間隔とフィルタ行を上部に追加
wks.labels(*P1O1); // 列パラメータ1、カテゴリ行を下部に追加
wks.labels(-F); //フィルタ行を非表示に
wks.labels(>C); //コメント行をラベル行の一番下に移動

// 列Bのロングネーム、単位、コメント、パラメータ1
col(B)[L]$ = "Temperature"; // ロングネーム
col(B)[U]$ = \+(o)C; // 単位
col(B)[C]$ = "Temperature vs Time"; // コメント
col(B)[P1]$ = "Site 1"; // 第一パラメータ行
 
// 列Bのサンプリング間隔を設定
wks.col2.xinit = 0.1;  // 初期値
wks.col2.xinc = 0.001;  // 間隔
wks.col2.xunits$ = "s";  // 単位
wks.col2.xname$ = "Time";  // 名前
 
// C列のF(x)セルを定義して値を設定
col(B)=normal(32); //列に通常のランダムな値を入力
col(C)[O]$="col(B)*2"; //C 列の値を計算する数式を入力
//wks.col3.formula$="col(B)*2"; // formula$も使用可

//スパークライン表示
wks.labels(*S); //スパークライン行を一番下に追加
sparklines sel:=0 c1:=1 c2:=3; //スパークラインをプロットするにはsparklines Xファンクションを使用

//列Aをカテゴリとして設定し、カテゴリセルの文字列を読み取り
patternT irng:=col(A) mode:=random text:="NY LA GZ HK" onerepeat:=2 seqrepeat:=4; //列Aにランダムなテキストを入力
set col(A) -dc 1; //列 A をカテゴリとして設定
col(A)[O1]$=; //カテゴリセルの文字列を読み取る
string str1$ = col(A)[O1]$; //カテゴリセルの文字列を文字列変数に読み取り;
str1$=; 
 
// ユーザ定義パラメータ 1 を追加し、D1文字を使用してアクセス
wks.labels(*D1); //最初のユーザ定義パラメータを表示
wks.UserParam1$ = "Mean"; //最初のユーザ定義パラメータの名前をMeanに変更
col(B)[D1]$ = $(mean(Col(B)),*3); //列Bの平均をMeanラベル行に入力し、有効数字3桁にします

//ユーザ定義パラメータ2を追加し、実際のユーザパラメータ名を使用してアクセス
wks.userparam2 = 1; //Size列ラベル行を表示します。wks.labels(*D2)と同じです。
wks.userparam2$ = Size; //2 番目のユーザー定義パラメータのSizeを定義
col(B)[Size]$ = $(count(Col(B),1),.0); //Size行に列Bのサイズを小数点以下0桁で入力

列ラベル行はメタデータまたは列に含まれるデータについての情報を含みます。 メタデータの使用方法の詳細については、メタデータへのアクセスセクションを参照してください。